10 AutoHotkey Scripts Đỉnh Cao Giúp Tối Ưu Hóa Trải Nghiệm Windows

Table of Contents

Trong nhiều năm qua, tôi đã quen với việc tạo ra các script PowerShell trên máy tính Windows của mình, nhưng hầu hết chúng đều phải chạy thủ công. Với AutoHotkey (phiên bản 2), tôi đã có thể tái tạo lại những script này và gán chúng vào các phím tắt, khiến chúng hoạt động giống như những tính năng tích hợp sẵn của Windows mà Microsoft “quên” không nhắc đến. AutoHotkey v2 đã biến đổi cách tôi tương tác với máy tính, giúp tự động hóa và tối ưu hóa các tác vụ hàng ngày, từ những việc nhỏ nhặt đến các quy trình làm việc phức tạp. Khám phá 10 AutoHotkey scripts này để nâng cao hiệu suất làm việc và cá nhân hóa trải nghiệm sử dụng Windows của bạn.

10. Trình Khởi Chạy Ứng Dụng Nhanh Cá Nhân

Menu ứng dụng tùy chỉnh được tạo bằng AutoHotkey

Các ứng dụng như Notepad, Calculator và Paint thường bị ẩn khỏi màn hình desktop của tôi vì chúng không quá quan trọng. Tuy nhiên, thỉnh thoảng tôi lại thấy mình phải mất công tìm kiếm các ứng dụng này để sử dụng nhanh chóng. Thay vì tìm kiếm trong menu Start hoặc các biểu tượng trên desktop, tôi đã tạo một menu tùy chỉnh xuất hiện ngay lập tức khi tôi nhấn tổ hợp phím Windows Key + M bằng script dưới đây.

#Requires AutoHotkey v2.0
#m::{
    MyMenu := Menu()
    MyMenu.Add("Calculator", (*) => Run("calc.exe"))
    MyMenu.Add("Sticky Notes", (*) => Run("explorer.exe shell:AppsFolderMicrosoft.MicrosoftStickyNotes_8wekyb3d8bbwe!App"))
    MyMenu.Add("Notepad", (*) => Run("notepad.exe"))
    MyMenu.Add("Paint", (*) => Run("mspaint.exe"))
    MyMenu.Show()
}

Tôi đã thiết lập menu này với Calculator, Sticky Notes, MS Paint và Notepad. Tuy nhiên, bạn có thể dễ dàng sửa đổi script để thêm các ứng dụng yêu thích của riêng mình. Bạn muốn thêm Notion? Chỉ cần nhân đôi một trong các dòng hiện có và thay đổi tên thành “Notion”, tìm tệp .exe của ứng dụng, sao chép đường dẫn của nó và dán vào bên trong dấu ngoặc đơn của lệnh Run.

Tôi thực sự rất thích menu tùy chỉnh này. Chỉ cần nhấn Windows + M, nhấp vào ứng dụng tôi muốn mở là xong. Không còn phải cuộn qua danh sách chương trình hay nhớ xem tôi đã ghim ứng dụng nào đó mà hiếm khi cần đến ở đâu. Tôi sử dụng nó vài lần mỗi ngày và nó giúp tôi tiết kiệm nhiều khoảnh khắc phiền toái nhỏ tích lũy lại.

9. Cuộn Ngang Nhất Quán

Việc giữ phím Shift + Cuộn chuột để cuộn ngang không hoạt động với tất cả các ứng dụng mà tôi sử dụng. Đáng tiếc, tôi thường xuyên thực hiện thao tác này, đặc biệt là khi tôi cần xem các đoạn code hoặc thiết kế trong CAD. Vì vậy, tôi đã tự tạo một script để làm cho tính năng cuộn ngang hoạt động nhất quán với bất kỳ ứng dụng nào tôi sử dụng.

Tạo một script với nội dung sau để tạo phiên bản của riêng bạn:

#Requires AutoHotkey v2.0
#HotIf GetKeyState("Shift", "P")
WheelUp::Send("{WheelLeft}")
WheelDown::Send("{WheelRight}")
#HotIf

Bằng cách giữ phím Shift và cuộn bánh xe chuột, tôi có thể cuộn sang trái và phải thay vì lên hoặc xuống. Điều này hoạt động trong bất kỳ chương trình nào hỗ trợ cuộn ngang, từ bảng tính Excel đến các trình chỉnh sửa ảnh hay trình duyệt web với nội dung rộng.

8. Truy Cập Thư Mục Bất Kỳ Ngay Lập Tức

Tôi thường xuyên tổ chức các tệp của mình bằng cách sử dụng các thư mục. Tuy nhiên, đôi khi tôi đã tạo quá nhiều thư mục con đến nỗi việc truy cập một thư mục dự án mất vài lần nhấp chuột. Sau đó, tôi nhận ra rằng mình có thể dễ dàng tạo một script gán vào tổ hợp phím Ctrl + Alt + D để ngay lập tức mở một thư mục dự án được chỉ định.

Đây là script:

#Requires AutoHotkey v2.0
^!d::Run('explorer.exe "C:UsersjricmDownloads"')

Bạn có thể dễ dàng sửa đổi script này bằng cách thêm đường dẫn thư mục của bạn (có dấu ngoặc kép) ngay sau ‘explorer.exe.’ Tất nhiên, bạn cũng có thể thay đổi các phím tắt bằng cách sử dụng các ký hiệu sửa đổi của AutoHotkey.

Điều tôi thích về cách tiếp cận này là nó trở nên tùy biến cao như thế nào khi bạn hiểu được quy luật. Tôi đã tạo ra các biến thể mở Desktop, thư mục Documents và thậm chí cả các thư mục dự án cụ thể mà tôi đang làm việc.

7. Mở Rộng Văn Bản Nhanh Chóng Cho Các Cụm Từ Hàng Ngày

Tôi thích ý tưởng sử dụng các mã Alt của Windows để dễ dàng và nhanh chóng chèn các ký tự đặc biệt. Tôi đã áp dụng cách tiếp cận tương tự với một script AHK cho phép tôi sử dụng các phím tắt cho các cụm từ thông dụng mà tôi thường dùng. Tạo script này để tự mình thử:

#Requires AutoHotkey v2.0
#SingleInstance Force
::gm::Good morning
::ty::Thank you
::brb::Be right back

Với ví dụ này, bất cứ khi nào tôi gõ “gm” theo sau là một khoảng trắng (hoặc Enter), nó sẽ ngay lập tức mở rộng thành “Good morning.” Tương tự với “ty,” sẽ mở rộng thành “Thank you,” và “brb” cho “Be right back.” Điều này hoạt động trong bất kỳ ứng dụng nào bạn có thể gõ và tôi thấy nó đặc biệt hữu ích khi tôi trả lời tin nhắn trong suốt cả ngày.

Nếu bạn muốn tùy chỉnh, chỉ cần thêm các từ viết tắt và cụm từ của riêng bạn theo cùng định dạng. Đây là một bổ sung nhỏ nhưng giúp tăng thêm tính trang trọng cho giao tiếp hàng ngày của tôi và giữ cho các phản hồi của tôi nhất quán. Có những cách khác để chèn các ký tự đặc biệt bằng phím tắt Windows, nhưng tôi thấy AutoHotkey cung cấp khả năng tùy chỉnh tốt nhất.

6. Điều Khiển Âm Lượng Tùy Chỉnh Cho Bàn Phím

Điều khiển âm lượng Windows bằng phím tắt tùy chỉnh trên bàn phím với AutoHotkey

Các điều khiển âm lượng của Windows luôn khiến tôi cảm thấy khó sử dụng. Bạn phải nhấp vào biểu tượng loa nhỏ trong khay hệ thống hoặc tìm kiếm các nút âm lượng trên bàn phím, điều này thật khó khăn, đặc biệt nếu bạn làm việc trong bóng tối như tôi. Tôi muốn một cái gì đó nhanh hơn và trực quan hơn.

Vì các ngón tay của tôi luôn bám vào các phím cơ sở (home row keys), việc gán điều khiển âm lượng vào tổ hợp phím CTRL + Dấu phẩy hoặc CTRL + Dấu chấm để điều khiển âm lượng, và CTRL + M để tắt/bật tiếng là hợp lý. Đây là script tôi đã sử dụng:

#Requires AutoHotkey v2.0
#SingleInstance Force
^,::Send("{Volume_Down}") ; Ctrl + ,
^.::Send("{Volume_Up}") ; Ctrl + .
^m::Send("{Volume_Mute}") ; Ctrl + M

Tôi đã chọn các tổ hợp phím này vì chúng không xung đột với các phím tắt thông dụng trong hầu hết các chương trình, và chúng luôn trong tầm với của ngón tay. Khi tôi đang trong một cuộc gọi video và âm thanh của ai đó quá lớn, tôi có thể nhanh chóng nhấn Ctrl + Dấu phẩy vài lần mà không làm gián đoạn quy trình làm việc hay phải loay hoay với chuột.

Mặc dù có nhiều cách để thiết lập điều khiển âm lượng tùy chỉnh trên bàn phím, tôi thích sử dụng AutoHotkey hơn. Nó mô phỏng các tín hiệu mà các phím âm lượng chuyên dụng gửi đi, đảm bảo khả năng tương thích với bất kỳ thiết bị âm thanh nào và tất cả các cài đặt âm thanh Windows của bạn. Nó thậm chí còn hiển thị lớp phủ âm lượng giống như khi bạn nhấn các nút âm lượng vật lý. Nếu bạn thích các tổ hợp phím khác, bạn có thể dễ dàng sửa đổi script. Có thể Ctrl + Cộng và Ctrl + Trừ sẽ tự nhiên hơn với bạn, hoặc có thể bạn muốn sử dụng các phím chức năng.

5. Canh Giữa Con Trỏ Chuột Ngay Lập Tức

Điều này nghe có vẻ đơn giản, nhưng nó lại hữu ích một cách đáng ngạc nhiên, đặc biệt nếu bạn làm việc với thiết lập đa màn hình hoặc màn hình siêu rộng. Phím tắt này sẽ căn giữa con trỏ chuột khi bạn nhấn Ctrl + Alt + C. Ban đầu tôi tạo nó cho mục đích chơi game, nhưng tôi thấy mình sử dụng nó suốt cả ngày. Đây là script bạn cần tạo:

#Requires AutoHotkey v2.0
^!c:: {
    WinGetPos(&x, &y, &w, &h, "A")
    MouseMove(x + w/2, y + h/2)
}

Script tìm điểm chính giữa của cửa sổ đang hoạt động và di chuyển chuột đến đó ngay lập tức. Nó hoạt động với bất kỳ chương trình nào và bất kỳ kích thước cửa sổ nào, ngay cả khi cửa sổ bị lệch khỏi màn hình một phần. Tôi sử dụng điều này thường xuyên nhất khi tôi chuyển đổi giữa các ứng dụng khác nhau và muốn nhanh chóng tập trung vào cửa sổ mới mà không cần phải suy nghĩ xem con chuột của tôi đã kết thúc ở đâu.

Bạn có thể sửa đổi script này để căn giữa con trỏ trên toàn bộ màn hình thay vì chỉ cửa sổ đang hoạt động, hoặc tạo các biến thể di chuyển con trỏ đến các vị trí cụ thể như góc trên bên trái hoặc góc dưới bên phải. Một số người thích con trỏ của họ tự động di chuyển đến nút đóng trên Windows, điều mà bạn có thể thực hiện với một sửa đổi nhỏ về vị trí.

4. Tự Động Sắp Xếp Thư Mục Tải Xuống

| Thư mục Downloads đã được sắp xếp tự động gọn gàng sau khi chạy script AutoHotkey |
| — | — |

Thư mục Downloads của tôi từng là một mớ hỗn độn. Ảnh chụp màn hình lẫn lộn với các tệp PDF, tệp nhạc bên cạnh các trình cài đặt ngẫu nhiên, mọi thứ chỉ bị đổ vào một đống khổng lồ. Tôi đã cố gắng tự sắp xếp, nhưng ai có thời gian để sắp xếp tệp khi bạn đang bận làm việc thực sự?

Script phím tắt này chạy ngầm và tự động sắp xếp các tệp tải xuống mới vào các thư mục đã được tổ chức dựa trên loại tệp. Tôi nhấn F12 để bật nó, và cứ sau năm giây nó sẽ quét thư mục Downloads của bạn và di chuyển các tệp vào các thư mục con thích hợp. Các tệp PDF và tài liệu Word đi vào thư mục “Docs”, hình ảnh đi vào “Images”, tệp nhạc vào “Music”, v.v. Đây là cách tôi thiết lập nó:

#Requires AutoHotkey v2.0
downloads:="C:UsersjricmDownloads", interval:=5000
ext:=Map("pdf","Docs","docx","Docs","xlsx","Docs","txt","Text","jpg","Images","png","Images","mp3","Music","mp4","Videos","exe","Programs","zip","Archives")
F12:: {
    static on:=false
    on:=!on, SetTimer(MoveFiles, on?interval:0)
    ToolTip("AutoSort: " (on?"ON":"OFF")), SetTimer(() => ToolTip(), -1500)
}
MoveFiles() {
    Loop Files downloads "*.*", "F"
    if ext.Has(e:=A_LoopFileExt) {
        d:=downloads "" ext[e]
        if !DirExist(d)
            DirCreate(d)
        try
            FileMove(A_LoopFilePath, d "" A_LoopFileName, 1)
    }
}

Script này tự động tạo các thư mục nếu chúng chưa tồn tại, vì vậy bạn không cần phải thiết lập bất cứ điều gì từ trước. Nó đủ thông minh để xử lý các xung đột tệp. Nếu bạn tải xuống hai tệp có cùng tên, nó sẽ không ghi đè lên tệp hiện có.

Nếu bạn cũng muốn sử dụng script tôi đã cung cấp, trước tiên bạn sẽ phải thay đổi đường dẫn thư mục bên cạnh biến “downloads”. Bạn cũng có thể thay đổi và thêm các phần mở rộng tệp khác bằng cách thêm loại phần mở rộng vào biến “ext”.

Có một chú giải công cụ nhỏ xuất hiện khi bạn bật hoặc tắt nó, nhưng ngoài ra nó chỉ âm thầm làm nhiệm vụ của mình trong nền. Khoảng thời gian năm giây có nghĩa là nó bắt kịp các tệp tải xuống mới một cách nhanh chóng mà không liên tục quét và làm chậm máy tính của bạn.

3. Khởi Chạy Nhiều Ứng Dụng Cho Các Quy Trình Làm Việc Cụ Thể

Tôi rất thích sử dụng các Màn hình ảo (Virtual Desktops) của Windows để tổ chức các tác vụ khác nhau. Thật đáng tiếc là nó không cho phép bạn tự động mở các ứng dụng nhất định hoặc thay đổi ứng dụng cho mỗi màn hình ảo. Để khắc phục, tôi đã sử dụng AutoHotkey để mở nhiều ứng dụng chỉ bằng một phím tắt. Đây là script tôi sử dụng:

#Requires AutoHotkey v2.0
+1:: {
    Run('"C:UsersjricmAppDataLocalProgramsMicrosoft VS CodeCode.exe"')
    Run('"C:Program FilesJetBrainsDataGrip 2023.3.4bindatagrip64.exe"')
    Run('"C:Program FilesDockerDockerDocker Desktop.exe"')
}

Bằng cách nhấn Shift + 1, script sẽ khởi chạy đồng thời các ứng dụng Visual Studio Code, DataGrip và Docker. Các ứng dụng này thường mất khá nhiều thời gian để tải (ngay cả khi không có script), vì vậy đây là cơ hội hoàn hảo để tôi đi pha cà phê hoặc sắp xếp không gian làm việc. Đến khi tôi sẵn sàng làm việc, cả ba chương trình đã mở và sẵn sàng. Điều này giúp tôi tiết kiệm được gánh nặng tinh thần phải nhớ những chương trình nào tôi cần cho các dự án nhất định, và thời gian phải nhấp chuột để khởi chạy từng cái một.

Tôi đã tạo một số biến thể của script này cho các loại công việc khác nhau. Shift + 2 khởi chạy thiết lập viết lách của tôi với Notion, Google và Asana. Shift + 3 mở thiết lập thiết kế 3D của tôi, bao gồm Fusion 360, Creality Print và YouTube Music. Có những trình khởi chạy quy trình làm việc chỉ bằng một phím tắt này giúp loại bỏ rào cản khi bắt đầu các loại dự án khác nhau.

2. Giữ Các Cửa Sổ Quan Trọng Luôn Hiển Thị

Có rất nhiều lúc tôi muốn một cửa sổ nào đó luôn hiển thị, chẳng hạn như khi tôi đang theo dõi một hướng dẫn, kiểm tra ghi chú hoặc trò chuyện với mọi người. Windows không cung cấp một cách dễ dàng để làm điều này. Vì vậy, tôi đã tạo một script cho mục đích cụ thể này.

#Requires AutoHotkey v2.0
ScrollLock:: {
    try {
        activeHwnd := WinGetID("A")
        isTopMost := WinGetExStyle(activeHwnd) & 0x8 ; 0x8 = WS_EX_TOPMOST

        WinSetAlwaysOnTop(!isTopMost, activeHwnd)
        SetScrollLockState(isTopMost ? "Off" : "On")

        ToolTip("Always On Top: " (isTopMost ? "OFF" : "ON"))
        SetTimer(() => ToolTip(), -1000)
    }
}

Với script trên, tôi chỉ cần nhấn phím Scroll Lock khi cửa sổ đang hoạt động, và nó sẽ nằm trên cùng của mọi thứ khác. Script hiển thị một chú giải công cụ nhanh và bật hoặc tắt đèn Scroll Lock trên bàn phím của tôi, vì vậy tôi luôn biết cửa sổ nào đang được ghim. Tôi sử dụng thủ thuật này mọi lúc khi tôi cần một cửa sổ tham chiếu tiện dụng mà không cần phải liên tục di chuyển mọi thứ xung quanh hoặc chuyển đổi qua lại. Scroll Lock là một lựa chọn tốt vì hầu hết mọi người không sử dụng nó cho bất kỳ mục đích nào khác, nhưng bạn có thể thay đổi nó thành một phím khác nếu muốn.

1. Ngăn Máy Tính Ngủ

Cài đặt thời gian hẹn giờ cho script chống ngủ máy tính của AutoHotkey

Đôi khi tôi tải xuống và truyền các tệp lớn trên máy tính của mình. Toàn bộ quá trình có thể mất vài phút đến vài giờ. Vấn đề của tôi là các tệp tải xuống thường bị gián đoạn do PC của tôi chuyển sang chế độ ngủ sau vài phút. Điều này luôn khiến tôi bực bội vì việc thử lại hoặc tiếp tục tải xuống thường thất bại. Để giải quyết vấn đề này, tôi đã tạo một script gắn với các phím Ctrl + Alt + Shift + S để bỏ qua hệ thống ngủ của máy tính một cách hiệu quả.

#Requires AutoHotkey v2.0
#SingleInstance Force

global on := false, endTime := 0

^!+s::{
    global on, endTime
    if !on {
        hrs := InputBox("Enter hours (0 = infinite):", "Anti-Sleep").Value
        if !IsNumber(hrs) || hrs is ""
            return MsgBox("Invalid input.")
        endTime := hrs ? A_TickCount + hrs*3600000 : 0
        SetTimer(AntiSleep, 300000), SetTimer(CheckEnd, 1000), on := true
        ToolTip("Anti-Sleep: ON" (hrs ? "`n" hrs "h" : ""), 500, 500), SetTimer(() => ToolTip(), -1500)
    } else {
        ; Required braces for multi-line else block
        SetTimer(AntiSleep, 0), SetTimer(CheckEnd, 0), on := false
        ToolTip("Anti-Sleep: OFF", 500, 500), SetTimer(() => ToolTip(), -1000)
    }
}

AntiSleep() => (MouseMove(1,0,0,"R"), MouseMove(-1,0,0,"R"))
CheckEnd() => endTime && A_TickCount >= endTime && Send("^!+s")
^!+x::Send("^!+s")

Script hoạt động bằng cách di chuyển chuột một chút sau mỗi năm phút. Bằng cách này, PC của tôi không chuyển sang trạng thái nhàn rỗi và ngủ. Gần đây tôi cũng đã mở rộng script để bao gồm một bộ hẹn giờ để tự động tắt script sau một khoảng thời gian nhất định. Script cũng hiển thị một chú giải công cụ nhỏ khi bạn kích hoạt hoặc tắt nó, vì vậy bạn luôn biết liệu nó có đang chạy hay không.

AutoHotkey có thể trông đáng sợ lúc đầu, nhưng bạn không cần phải hiểu từng dòng code để hưởng lợi từ nó. Hãy tải AutoHotkey về và bắt đầu với một hoặc hai script giải quyết các vấn đề bạn thực sự gặp phải. Khi bạn đã quen với cách chúng hoạt động, hãy dần dần thêm nhiều hơn khi bạn khám phá những cách mới để cải thiện quy trình làm việc của mình. Chia sẻ những AutoHotkey scripts yêu thích của bạn hoặc cách bạn đã tùy chỉnh Windows để làm việc hiệu quả hơn trong phần bình luận bên dưới nhé!